hunfabric/modules/ncc-spoke-ra

NCC Spoke RA Module

This module allows management of NCC Spokes backed by Router Appliances. Network virtual appliances used as router appliances allow to connect an external network to Google Cloud by using a SD-WAN router or another appliance with BGP capabilities (site-to-cloud connectivity). It is also possible to enable site-to-site data transfer, although this feature is not available in all regions, particularly not in EMEA.

The module manages a hub (optionally), a spoke, and the corresponding Cloud Router and BGP sessions to the router appliance(s).

Examples

Simple hub & spoke

module "spoke-ra" {
  source     = "./fabric/modules/ncc-spoke-ra"
  hub        = { create = true, name = "ncc-hub" }
  name       = "spoke-ra"
  project_id = var.project_id
  region     = var.region
  router_appliances = [
    {
      internal_ip  = module.compute-vm-primary-b.internal_ip
      vm_self_link = module.compute-vm-primary-b.self_link
    }
  ]
  router_config = {
    asn           = 65000
    ip_interface0 = "10.0.16.14"
    ip_interface1 = "10.0.16.15"
    peer_asn      = 65001
  }
  vpc_config = {
    network_name     = var.vpc.self_link
    subnet_self_link = var.subnet.self_link
  }
}
# tftest modules=5 resources=11 fixtures=fixtures/compute-vm-nva.tf e2e

Two spokes

resource "google_network_connectivity_hub" "default" {
  name        = "Hub"
  description = "Hub"
  project     = var.project_id
}

module "spoke-ra-a" {
  source     = "./fabric/modules/ncc-spoke-ra"
  hub        = { id = google_network_connectivity_hub.default.id }
  name       = "spoke-ra-a"
  project_id = var.project_id
  region     = var.regions.primary
  router_appliances = [
    {
      internal_ip  = module.compute-vm-primary-b.internal_ip
      vm_self_link = module.compute-vm-primary-b.self_link
    }
  ]
  router_config = {
    asn           = 65000
    ip_interface0 = "10.0.16.14"
    ip_interface1 = "10.0.16.15"
    peer_asn      = 65001
  }
  vpc_config = {
    network_name     = var.vpc.self_link
    subnet_self_link = var.subnets.primary.self_link
  }
}

module "spoke-ra-b" {
  source     = "./fabric/modules/ncc-spoke-ra"
  hub        = { id = google_network_connectivity_hub.default.id }
  name       = "spoke-ra-b"
  project_id = var.project_id
  region     = var.regions.secondary
  router_appliances = [
    {
      internal_ip  = module.compute-vm-secondary-b.internal_ip
      vm_self_link = module.compute-vm-secondary-b.self_link
    }
  ]
  router_config = {
    asn           = 65000
    ip_interface0 = "10.1.16.14"
    ip_interface1 = "10.1.16.15"
    peer_asn      = 65002
  }
  vpc_config = {
    network_name     = var.vpc.self_link
    subnet_self_link = var.subnets.secondary.self_link
  }
}
# tftest modules=6 resources=17 fixtures=fixtures/compute-vm-nva.tf e2e

Spoke with load-balanced router appliances

resource "google_network_connectivity_hub" "default" {
  name        = "Hub"
  description = "Hub"
  project     = var.project_id
}

module "spoke-ra" {
  source     = "./fabric/modules/ncc-spoke-ra"
  hub        = { id = google_network_connectivity_hub.default.id }
  name       = "spoke-ra"
  project_id = var.project_id
  region     = var.region
  router_appliances = [
    {
      internal_ip  = module.compute-vm-primary-b.internal_ip
      vm_self_link = module.compute-vm-primary-b.self_link
    },
    {
      internal_ip  = module.compute-vm-primary-c.internal_ip
      vm_self_link = module.compute-vm-primary-c.self_link
    }
  ]
  router_config = {
    asn = 65000
    custom_advertise = {
      all_subnets = true
      ip_ranges = {
        "10.10.0.0/24" = "peered-vpc"
      }
    }
    ip_interface0 = "10.0.16.14"
    ip_interface1 = "10.0.16.15"
    peer_asn      = 65001
  }
  vpc_config = {
    network_name     = var.vpc.self_link
    subnet_self_link = var.subnet.self_link
  }
}
# tftest modules=5 resources=13 fixtures=fixtures/compute-vm-nva.tf e2e

Variables

name	description	type	required	default
hub	The NCC hub. You should either provide an existing hub id or a hub name if create is true.	object({…})	✓
name	The name of the NCC spoke.	string	✓
project_id	The ID of the project where the NCC hub & spokes will be created.	string	✓
region	Region where the spoke is located.	string	✓
router_appliances	List of router appliances this spoke is associated with.	list(object({…}))	✓
router_config	Configuration of the Cloud Router.	object({…})	✓
vpc_config	Network and subnetwork for the CR interfaces.	object({…})	✓
data_transfer	Site-to-site data transfer feature, available only in some regions.	bool		false

Outputs

name	description	sensitive
hub	NCC hub resource (only if auto-created).
id	Fully qualified hub id.
router	Cloud Router resource.
spoke-ra	NCC spoke resource.

Fixtures

• compute-vm-nva.tf