725f7effce
* preliminary support for wif in stage 0 * IAM wif role * IAM wif role TODO * add support for external SA IAM to SA module * add name output to SA module * separate cicd SA * tfdoc * GITLAB principal (untested) * make GCS name output static * outputs bucket * fix stage 1 test * tweak outputs * tfdoc * move wif_pool to automation variable * add support for top-level and repository providers * add missing boilerplate * fix branchless principal * initial workflow * symlink provider template in stages * remove service accounts from stage 0 cicd tfvars * add cicd interface variable to resman stage * fix cicd variable in resman stage * better condition on outputs_location * fix last change * change outputs_location type * revert outputs_location change * split outputs in stage 0 * update ci/cd temporary notes * rename additive IAM resource in SA module * split outputs in stage 1 * remove unused locals * fix stage 1 tests * tfdoc * Upload action files to outputs_bucket * Fix tests and README * rename template, streamline outputs * local templates and gcs output for all stage 2 * add workflows to local output files * Use lowercase WIF providers everywhere * Bring back suffix for workflow files * Remove unused files * Update READMEs * preliminary CI/CD implementation for stage 1 * fix stage 1 * stage 1 cicd * tfdoc * fix tests * readme and links for cicd and wif * refactor wif providers * refactor cicd for stage 1 * fix stage 1 * wif org policies * split identity provider configuration from cicd * add type attribute to cicd repositories * valid cicd repositories have a workflow template * refactor stage 01 * fix stage 01 tests * minimal CI/CD documentation * better check_links error reporting * fix links * Added Gitlab specific configurations Set the default issuer_uri for Gitlab. Added allowed audiences to OIDC configuration. * Fixed TF formatting in identity providers. * Changing identity provider audience to null Changing identity provider audience to default to null. * add instructions for renaming workflows * address Julio's comments Co-authored-by: Julio Castillo <jccb@google.com> Co-authored-by: alexmeissner <alexmeissner@google.com>
87 lines
3.1 KiB
HCL
87 lines
3.1 KiB
HCL
/**
|
|
* Copyright 2022 Google LLC
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
|
|
locals {
|
|
# https://github.com/hashicorp/terraform/issues/22405#issuecomment-591917758
|
|
key = try(
|
|
var.generate_key
|
|
? google_service_account_key.key["1"]
|
|
: map("", null)
|
|
, {})
|
|
prefix = var.prefix != null ? "${var.prefix}-" : ""
|
|
resource_email_static = "${local.prefix}${var.name}@${var.project_id}.iam.gserviceaccount.com"
|
|
resource_iam_email = (
|
|
local.service_account != null
|
|
? "serviceAccount:${local.service_account.email}"
|
|
: local.resource_iam_email_static
|
|
)
|
|
resource_iam_email_static = "serviceAccount:${local.resource_email_static}"
|
|
service_account = (
|
|
var.service_account_create
|
|
? try(google_service_account.service_account.0, null)
|
|
: try(data.google_service_account.service_account.0, null)
|
|
)
|
|
service_account_credential_templates = {
|
|
for file, _ in local.public_keys_data : file => jsonencode(
|
|
{
|
|
type : "service_account",
|
|
project_id : var.project_id,
|
|
private_key_id : split("/", google_service_account_key.upload_key[file].id)[5]
|
|
private_key : "REPLACE_ME_WITH_PRIVATE_KEY_DATA"
|
|
client_email : local.resource_email_static
|
|
client_id : local.service_account.unique_id,
|
|
auth_uri : "https://accounts.google.com/o/oauth2/auth",
|
|
token_uri : "https://oauth2.googleapis.com/token",
|
|
auth_provider_x509_cert_url : "https://www.googleapis.com/oauth2/v1/certs",
|
|
client_x509_cert_url : "https://www.googleapis.com/robot/v1/metadata/x509/${urlencode(local.resource_email_static)}"
|
|
}
|
|
)
|
|
}
|
|
public_keys_data = (
|
|
var.public_keys_directory != ""
|
|
? {
|
|
for file in fileset("${path.root}/${var.public_keys_directory}", "*.pem")
|
|
: file => filebase64("${path.root}/${var.public_keys_directory}/${file}") }
|
|
: {}
|
|
)
|
|
}
|
|
|
|
|
|
data "google_service_account" "service_account" {
|
|
count = var.service_account_create ? 0 : 1
|
|
project = var.project_id
|
|
account_id = "${local.prefix}${var.name}"
|
|
}
|
|
|
|
resource "google_service_account" "service_account" {
|
|
count = var.service_account_create ? 1 : 0
|
|
project = var.project_id
|
|
account_id = "${local.prefix}${var.name}"
|
|
display_name = var.display_name
|
|
description = var.description
|
|
}
|
|
|
|
resource "google_service_account_key" "key" {
|
|
for_each = var.generate_key ? { 1 = 1 } : {}
|
|
service_account_id = local.service_account.email
|
|
}
|
|
|
|
resource "google_service_account_key" "upload_key" {
|
|
for_each = local.public_keys_data
|
|
service_account_id = local.service_account.email
|
|
public_key_data = each.value
|
|
}
|