f94033f098
* refactor(net-lb-app-ext): improve configurability and resource references - Allow overriding names for backend buckets and instance groups - Add optional per-group description with default value - Use self_link for instance group backend references - Fix HTTP proxy name to use http_proxy_config * reverted the instance group reference in backend service back to id instead of self link * updated all the lb modules for unmanaged instance groups to have flexible names and proper refactorization of http_proxy_cofig in each module * removed the description variable * updated the readme.md for the net-lb-app-ext-regional module * fixed the linting error for the change in versions.tf --------- Co-authored-by: Julio Castillo <jccb@google.com> Co-authored-by: Ludovico Magnocavallo <ludomagno@google.com>
80 lines
3.1 KiB
HCL
80 lines
3.1 KiB
HCL
/**
|
|
* Copyright 2024 Google LLC
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
|
|
locals {
|
|
fwd_rule_ports = (
|
|
var.protocol == "HTTPS" ? [443] : coalesce(var.ports, [80])
|
|
)
|
|
fwd_rule_target = (
|
|
var.protocol == "HTTPS"
|
|
? google_compute_region_target_https_proxy.default[0].id
|
|
: google_compute_region_target_http_proxy.default[0].id
|
|
)
|
|
proxy_ssl_certificates = concat(
|
|
coalesce(var.ssl_certificates.certificate_ids, []),
|
|
[for k, v in google_compute_region_ssl_certificate.default : v.id],
|
|
)
|
|
}
|
|
|
|
resource "google_compute_forwarding_rule" "default" {
|
|
provider = google-beta
|
|
project = var.project_id
|
|
name = var.name
|
|
region = var.region
|
|
description = var.description
|
|
ip_address = var.address
|
|
ip_protocol = "TCP"
|
|
load_balancing_scheme = "EXTERNAL_MANAGED"
|
|
port_range = join(",", local.fwd_rule_ports)
|
|
labels = var.labels
|
|
target = local.fwd_rule_target
|
|
network = var.vpc
|
|
network_tier = var.network_tier_standard ? "STANDARD" : "PREMIUM"
|
|
}
|
|
|
|
resource "google_compute_region_ssl_certificate" "default" {
|
|
for_each = var.ssl_certificates.create_configs
|
|
project = var.project_id
|
|
name = coalesce(each.value.name, "${var.name}-${each.key}")
|
|
region = var.region
|
|
certificate = trimspace(each.value.certificate)
|
|
private_key = trimspace(each.value.private_key)
|
|
lifecycle {
|
|
create_before_destroy = true
|
|
}
|
|
}
|
|
|
|
resource "google_compute_region_target_http_proxy" "default" {
|
|
count = var.protocol == "HTTPS" ? 0 : 1
|
|
project = var.project_id
|
|
region = var.region
|
|
name = coalesce(var.http_proxy_config.name, var.name)
|
|
description = var.http_proxy_config.description
|
|
url_map = google_compute_region_url_map.default.id
|
|
}
|
|
|
|
resource "google_compute_region_target_https_proxy" "default" {
|
|
count = var.protocol == "HTTPS" ? 1 : 0
|
|
project = var.project_id
|
|
name = coalesce(var.https_proxy_config.name, var.name)
|
|
region = var.region
|
|
description = var.https_proxy_config.description
|
|
certificate_manager_certificates = var.https_proxy_config.certificate_manager_certificates
|
|
ssl_certificates = length(local.proxy_ssl_certificates) == 0 ? null : local.proxy_ssl_certificates
|
|
ssl_policy = var.https_proxy_config.ssl_policy
|
|
url_map = google_compute_region_url_map.default.id
|
|
}
|