71a64487d5
* add doc draft * typos * typo * typo * typos * rewording * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Update 0-domainless-iam.md * move iam variables to a separate file * move billing-account module to iam_principals * move data-catalog-policy-tag module to iam_principals * move dataplex-datascan module to iam_principals * move dataproc module to iam_principals * move folder module to iam_principals * copyright * move organization module to iam_principals * move project module to iam_principals * move source-repository module to iam_principals * update blueprints for iam_principals interface * FAST bootstrap * module READMEs fixes * FAST bootstrap * FAST networking stages * FAST security stage * FAST gke stage * FAST multitenant bootstrap stage * FAST multitenant resman stage * tfdoc * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Update 0-domainless-iam.md * fix module test * Update 0-domainless-iam.md * Update 0-domainless-iam.md * Rename iam_principals to iam_by_principals * Update IAM template to include iam_by_principals * Update Resman README * Fix ADR link format --------- Co-authored-by: Julio Castillo <jccb@google.com>
76 lines
2.5 KiB
HCL
76 lines
2.5 KiB
HCL
/**
|
|
* Copyright 2024 Google LLC
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
|
|
locals {
|
|
_iam_principal_roles = distinct(flatten(values(var.iam_by_principals)))
|
|
_iam_principals = {
|
|
for r in local._iam_principal_roles : r => [
|
|
for k, v in var.iam_by_principals :
|
|
k if try(index(v, r), null) != null
|
|
]
|
|
}
|
|
iam = {
|
|
for role in distinct(concat(keys(var.iam), keys(local._iam_principals))) :
|
|
role => concat(
|
|
try(var.iam[role], []),
|
|
try(local._iam_principals[role], [])
|
|
)
|
|
}
|
|
}
|
|
|
|
resource "google_dataplex_datascan_iam_binding" "authoritative_for_role" {
|
|
for_each = local.iam
|
|
project = google_dataplex_datascan.datascan.project
|
|
location = google_dataplex_datascan.datascan.location
|
|
data_scan_id = google_dataplex_datascan.datascan.data_scan_id
|
|
role = each.key
|
|
members = each.value
|
|
}
|
|
|
|
resource "google_dataplex_datascan_iam_binding" "bindings" {
|
|
for_each = var.iam_bindings
|
|
project = google_dataplex_datascan.datascan.project
|
|
location = google_dataplex_datascan.datascan.location
|
|
data_scan_id = google_dataplex_datascan.datascan.data_scan_id
|
|
role = each.value.role
|
|
members = each.value.members
|
|
dynamic "condition" {
|
|
for_each = each.value.condition == null ? [] : [""]
|
|
content {
|
|
expression = each.value.condition.expression
|
|
title = each.value.condition.title
|
|
description = each.value.condition.description
|
|
}
|
|
}
|
|
}
|
|
|
|
resource "google_dataplex_datascan_iam_member" "bindings" {
|
|
for_each = var.iam_bindings_additive
|
|
project = google_dataplex_datascan.datascan.project
|
|
location = google_dataplex_datascan.datascan.location
|
|
data_scan_id = google_dataplex_datascan.datascan.data_scan_id
|
|
role = each.value.role
|
|
member = each.value.member
|
|
dynamic "condition" {
|
|
for_each = each.value.condition == null ? [] : [""]
|
|
content {
|
|
expression = each.value.condition.expression
|
|
title = each.value.condition.title
|
|
description = each.value.condition.description
|
|
}
|
|
}
|
|
}
|