67b1543e90
* extend attributes for project factory secondary resources * remove extra files * complete * tf fmt * tfdoc * schemas * fix tests * tfdoc
83 lines
2.7 KiB
HCL
83 lines
2.7 KiB
HCL
/**
|
|
* Copyright 2024 Google LLC
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
|
|
# tfdoc:file:description IAM bindings.
|
|
|
|
locals {
|
|
_iam_principal_roles = distinct(flatten(values(var.iam_by_principals)))
|
|
_iam_principals = {
|
|
for r in local._iam_principal_roles : r => [
|
|
for k, v in var.iam_by_principals :
|
|
k if try(index(v, r), null) != null
|
|
]
|
|
}
|
|
iam = {
|
|
for role in distinct(concat(keys(var.iam), keys(local._iam_principals))) :
|
|
role => concat(
|
|
try(var.iam[role], []),
|
|
try(local._iam_principals[role], [])
|
|
)
|
|
}
|
|
}
|
|
|
|
resource "google_bigquery_dataset_iam_binding" "authoritative" {
|
|
for_each = local.iam
|
|
project = local.project_id
|
|
dataset_id = google_bigquery_dataset.default.dataset_id
|
|
role = lookup(local.ctx.custom_roles, each.key, each.key)
|
|
members = [
|
|
for v in each.value : lookup(local.ctx.iam_principals, v, v)
|
|
]
|
|
}
|
|
|
|
resource "google_bigquery_dataset_iam_binding" "bindings" {
|
|
for_each = var.iam_bindings
|
|
project = local.project_id
|
|
dataset_id = google_bigquery_dataset.default.dataset_id
|
|
role = lookup(local.ctx.custom_roles, each.value.role, each.value.role)
|
|
members = [
|
|
for v in each.value.members : lookup(local.ctx.iam_principals, v, v)
|
|
]
|
|
dynamic "condition" {
|
|
for_each = each.value.condition == null ? [] : [""]
|
|
content {
|
|
expression = templatestring(
|
|
each.value.condition.expression, var.context.condition_vars
|
|
)
|
|
title = each.value.condition.title
|
|
description = each.value.condition.description
|
|
}
|
|
}
|
|
}
|
|
|
|
resource "google_bigquery_dataset_iam_member" "bindings" {
|
|
for_each = var.iam_bindings_additive
|
|
project = local.project_id
|
|
dataset_id = google_bigquery_dataset.default.dataset_id
|
|
role = lookup(local.ctx.custom_roles, each.value.role, each.value.role)
|
|
member = lookup(local.ctx.iam_principals, each.value.member, each.value.member)
|
|
dynamic "condition" {
|
|
for_each = each.value.condition == null ? [] : [""]
|
|
content {
|
|
expression = templatestring(
|
|
each.value.condition.expression, var.context.condition_vars
|
|
)
|
|
title = each.value.condition.title
|
|
description = each.value.condition.description
|
|
}
|
|
}
|
|
}
|