/**
 * Copyright 2023 Google LLC
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

locals {
  region = regex("([a-z]*-[a-z]*[0-9]{1,2})-([a-z])", var.zone)[0]
  vmw_network = (
    var.vmw_network_create
    ? try(google_vmwareengine_network.private-cloud-network.0, null)
    : try(data.google_vmwareengine_network.private-cloud-network.0, null)
  )
  tenant_host_project = {
    for k, v in var.private_connections : k => v.tenant_host_project == null
    ? regex("(.*)/projects/([a-z0-9-]*)/(.*)", "${data.google_compute_network_peering.psa_peering[k].peer_network}")[1]
    : v.tenant_host_project
  }
}

data "google_vmwareengine_network" "private-cloud-network" {
  count    = var.vmw_network_create ? 0 : 1
  provider = google-beta
  project  = var.project_id
  name     = "${local.region}-default"
  location = local.region
}

data "google_compute_network_peering" "psa_peering" {
  for_each = { for k, v in var.private_connections : k => v if v.tenant_host_project == null }
  name     = each.value.peering_name
  network  = each.value.network_self_link
}

resource "google_vmwareengine_private_cloud" "private-cloud" {
  provider    = google-beta
  project     = var.project_id
  location    = var.zone
  name        = var.name
  description = var.description

  network_config {
    management_cidr       = var.cidr
    vmware_engine_network = local.vmw_network.id
  }

  management_cluster {
    cluster_id = "${var.name}-mgmt-cluster"
    node_type_configs {
      node_type_id      = var.management_cluster_config.node_type_id
      node_count        = var.management_cluster_config.node_count
      custom_core_count = var.management_cluster_config.custom_core_count
    }
  }
}

resource "google_vmwareengine_network" "private-cloud-network" {
  count       = var.vmw_network_create ? 1 : 0
  provider    = google-beta
  project     = var.project_id
  name        = "${local.region}-default"
  location    = local.region
  type        = "LEGACY"
  description = var.vmw_network_description
}
